pro toggle,color=color,landscape=landscape,portrait=portrait,letter=letter, $
                       legal=legal,print=print,filename=filename
;+
; ROUTINE:      toggle,color=color,landscape=landscape,portrait=portrait, $
;                      letter=letter,legal=legal,filename=filename
;
; PURPOSE:      toggles IDL graphics output between X-window and a postscript
;               output file.
;
; OPTIONAL INPUTS (keyword parameters):
;
;   COLOR       Enable color plotting (output to Tek Phaser color printer)
;
;   LANDSCAPE   Horizontal plotting format
;   PORTRAIT    Vertical plotting format (default)
;
;   LETTER      8.5 by 11 inch page size (default)
;   LEGAL       11 by 14 inch page size (Phaser)
;
;   PRINT       1 = submit to LAB print queue
;               2 = submit to GAUTIER print queue
;               3 = submit to PHASER print queue
;
;   FILENAME    name of postscript file (default = plot.ps or plotc.ps)
;
; PROCEDURE:    The first call to TOGGLE (and all odd number calls) 
;               changes the output device from X-window to a
;               Postscript output file.  If the output file name is not
;               specified on the command line the default file name will
;               be plot.ps for the laser printers, or plotc.ps for the 
;               TEK Phaser color printer. 
;
;               The next call (and all even number calls) switches back 
;               to the X-window and closes the plot file.  If the keyword
;               PRINT is set the plotfile will be submitted to one of the
;               ESRG print queues.  
;
;               NOTE: Only one postscript file can be open at any given time
;
; EXAMPLE:
;               View the IDL dist function and then make a hardcopy:
;
;               IDL> d=dist(200)
;               IDL> loadct,5
;               IDL> tvscl,d                    ; view the plot on X-windows
;               IDL> toggle,/color,/landscape   ; redirect output to plotc.ps
;               IDL> tvscl,d                    ; write plot onto plotc.ps
;               IDL> toggle,/print              ; resume output to X-windows
;                                               ; submit plot to LAB printer
;               
;
; AUTHOR        Paul Ricchiazzi       ESRG     1jun92
; 
; REVISIONS:
;  3feb93: added PRINT keyword
; 24feb93: set yoffset=10.5 in hp landscape mode
; 26feb93: added FILENAME keyword
;-
;
common toggle_blk,psfile

if !d.name eq 'X' then begin
  set_plot, 'PS'
  if keyword_set(color) eq 0 then begin
    if keyword_set(filename) eq 0 then psfile='plot.ps' else psfile=filename
;
; HP Laserjet
;
    if keyword_set(landscape) eq 0 then begin	
      device, filename=psfile,xsize=7,ysize=10,yoffset=0.5,/inches, $
          /portrait
    endif else begin
      device, filename=psfile,xsize=10,ysize=7,yoffset=10.5,/inches, $
          /landscape
    endelse
    print, 'Output directed to ',psfile,', for output on HP Laserjet'
  endif else begin
;
; Tektronics Phaser color printer
;
    if keyword_set(filename) eq 0 then psfile='plotc.ps' else psfile=filename
    short_side = 8.0
    small_offset=(8.5-short_side)/2.
    set_plot, 'ps'
    if n_elements(legal) ne 0 then begin
      long_side=10.5
      big_offset=(14.-long_side)/2.
    endif else begin
      long_side=8.5
      big_offset=(11.-long_side)/2
    endelse
    if n_elements(portrait) ne 0 then begin
      up_shift=0.  ;   up shift in inches
      yoffset=big_offset+up_shift
      print,form='(5a10)','portrait','xsize','ysize','xoffset','yoffset'
      print,form='(10x,4g10.5)',short_side,long_side,small_offset,yoffset
      device, bits=8, /color, xsize=short_side, ysize=long_side, $
             xoffset=small_offset, yoffset=yoffset, $
             /inch, /portrait,file=psfile
    endif else begin
      left_shift=.5;    left shift in inches
      yoffset=long_side+big_offset+left_shift
      print,form='(5a10)','landscape','xsize','ysize','xoffset','yoffset'
      print,form='(10x,4g10.5)',long_side,short_side,small_offset,yoffset
      device, bits=8, /color, xsize=long_side, ysize=short_side, $
             xoffset=small_offset, yoffset=yoffset, $
             /inch, /landscape,file=psfile
    endelse
    print, 'Color output directed to file ',psfile,', for output on Phaser'
  endelse  
;
;
endif else begin
  device, /close_file 
  print,'file '+psfile+' closed. Output directed to Xwindow  ' 
  set_plot, 'X' 
  if keyword_set(print) then begin
    case print of
      1:spawn,'lpr           '+ psfile
      2:spawn,'lpr -Pgautier '+ psfile
      3:spawn,'lpr -Pphaser  '+ psfile
    end
  endif
endelse
return
end